# Version May 14, 2023
# ----------------------------------------------------------------------
# This file is called by .cshrc to initialize environment variables
# and set up the path.

# BIRCH_DEBUG = 1 will cause each successive cshrc.source, platform.source
# etc. to each print progress messages.

set BIRCH_DEBUG = 0
if ( $BIRCH_DEBUG == 1 ) echo Running cshrc.source

################################################################
#                     PLATFORM-SPECIFIC SETTINGS               #
################################################################

##*******************************************************
## LOCATION OF BIRCH. The following line that sets the BIRCH
## environment variable is generated during installation and
## updating. This file should never be edited manually.
## All local changes should  be made in $BIRCH/local/admin
##*******************************************************

setenv BIRCH /home/psgendb

# Get critical platform-specific settings, which will
# govern how other settings are made. If you have additional
# commands that you want to override commands in this file,
# put them in $BIRCH/local/admin/cshrc.source, which is called
# at the end of this file.
source $BIRCH/local/admin/platform.source



################################################################
#                         GLOBAL SETTINGS                      #
################################################################

#----------------- BIRCH ENVIRONMENT VARIABLES ---------------------
#useful environment variables for sequence work
# both upper and lowercase equivalents are permitted

setenv birch   $BIRCH
setenv LOCAL   $BIRCH/local
setenv local   $LOCAL

# Documentation and data directories
setenv DOC     $BIRCH/doc
setenv doc     $DOC
setenv DAT     $BIRCH/dat
setenv dat     $DAT
setenv TUTORIALS $BIRCH/tutorials
setenv tutorials $TUTORIALS

# Databases
setenv GENBANK $BIRCH/GenBank 
setenv genbank $GENBANK
setenv GB      $GENBANK
setenv gb      $GENBANK
setenv PIR     $BIRCH/PIR
setenv pir     $PIR
setenv RE      $BIRCH/REBASE
setenv BLASTDB $GENBANK  # databases used by standalone blast

# BIRCHLIBS - libraries for Python scripts
setenv BIRCHPYLIB $BIRCH/script/birchpylib


#-------------------------------------------------


# Use this for a more diverse server cluster
# Platform-specific setup commands
# BIRCH_BIN - location of BIRCH binaries
# RM_CMD - file to use for 'rm' command
setenv BIRCHLIBS  ""

# Apple is transitioning from the Intel architecture to ARM64.
# We want to put bin-macos-arm64 (BIRCH_BIN) first in the PATH, so that
# native arm64 binaries are found first. If a program is not
# available for arm64, the shell will search for it in 
# bin-osx-x86_64 (BIRCH_BIN_ALT). The Intel binaries in that directory
# will be run in emulated mode by Rosetta2.
setenv BIRCH_BIN_ALT  ""
switch ($BIRCH_PLATFORM)
  case "solaris-sparc":
    setenv BIRCH_BIN  bin-solaris-sparc
    setenv RM_CMD /usr/bin/rm
    breaksw  
  case "solaris-amd64":
    setenv BIRCH_BIN  bin-solaris-amd64
    setenv RM_CMD /usr/bin/rm
    breaksw
  case "linux-intel":
    setenv BIRCH_BIN  bin-linux-intel
    setenv RM_CMD /bin/rm
    breaksw
  case "linux-x86_64":
    setenv BIRCH_BIN  bin-linux-x86_64
    setenv RM_CMD /bin/rm
    breaksw
  case "linux-arm64":
    setenv BIRCH_BIN  bin-linux-arm64
    setenv RM_CMD /bin/rm
    breaksw
  case "osx-x86_64":
    setenv BIRCH_BIN  bin-osx-x86_64
    setenv RM_CMD /bin/rm
    breaksw    
  case "macos-arm64":
    setenv BIRCH_BIN  bin-macos-arm64
    setenv BIRCH_BIN_ALT bin-osx-x86_64
    setenv RM_CMD /bin/rm
    breaksw    
  case "winxp-32":
    setenv BIRCH_BIN  bin-winxp-32
    setenv RM_CMD /usr/bin/rm
    breaksw
  case "win7-64":
    setenv BIRCH_BIN  bin-win7-64
    setenv RM_CMD /usr/bin/rm
    breaksw
  default:
    setenv BIRCH_BIN  bin-linux-x86_64
    setenv RM_CMD /usr/bin/rm
    breaksw
endsw

# $BIRCH/script is for scripts that work on all platforms
# $BIRCH_BIN is a bin directory, chosen in cshrc.source,
# with platform-specific binaries
set COUNT = `echo $path | grep -c $BIRCH_BIN`
if ( "$COUNT" == "0" ) then
    if ( "$BIRCH_PLATFORM" == "macos-arm64" ) then
        set path = ($BIRCH/local/script $BIRCH/local/$BIRCH_BIN $BIRCH/local/$BIRCH_BIN_ALT $path $BIRCH/script $BIRCH/$BIRCH_BIN $BIRCH/$BIRCH_BIN_ALT )
    else
        set path = ($BIRCH/local/script $BIRCH/local/$BIRCH_BIN $path $BIRCH/script $BIRCH/$BIRCH_BIN)
    endif
endif

# Set Manual path
switch ($BIRCH_PLATFORM)
  case "solaris-*":
	if ${?MANPATH} then
	   set COUNT = `echo "$MANPATH" | grep -c $BIRCH`
           if ($COUNT == "0") \
	      setenv MANPATH $MANPATH\:$BIRCH\:$BIRCH/local
	else
	   setenv MANPATH $BIRCH\:\$BIRCH/local
	endif
    breaksw

# On Debian Linux, man -w doesn't work, and there is no alternative
# switch that works for linux distributions. For now the workaround
# is just to check the $MANPATH variable.
#  case "linux-*":
#	setenv MANPATH `man -w`:$BIRCH\:$BIRCH/local
#    breaksw
  default:
        # This is probably safest, when we don't know how
	# man works on a system.If you try setting MANPATH
	# on a system that uses /etc/man.config, you clobber
	# all manual pages other than the BIRCH pages.
	if ${?MANPATH} then
	   set COUNT = `echo "$MANPATH" | grep -c $BIRCH`
           if ($COUNT == "0") \	
	      setenv MANPATH $MANPATH\:$BIRCH\:$BIRCH/local
	else
	   setenv MANPATH $BIRCH\:\$BIRCH/local
	endif	      
    breaksw
endsw

#------------------------ BIRCH SETTINGS --------------
# Get values of environment variables
if (-e $BIRCH/admin/birch_settings_csh.source) \
    source $BIRCH/admin/birch_settings_csh.source

setenv BIRCH_PROMPT "Y"

# Personal setting for prompt overrides all other settings.
if ( -e $HOME/.config/BIRCH/BIRCHsettings.source ) then
    set result=`grep 'BIRCH_PROMPT=N' $HOME/.config/BIRCH/BIRCHsettings.source`
    if ( "$result" != "" ) then
        setenv BIRCH_PROMPT "N"
    endif
endif

if ( "$BIRCH_PROMPT" == "Y" ) then
    if ( -e $BIRCH/local/admin/set_birch_prompt_csh.source ) then
          # Local settings override default settings
        source $BIRCH/local/admin/set_birch_prompt_csh.source
    else # default
        source $BIRCH/admin/set_birch_prompt_csh.source
    endif
endif

#------------------------ TEMPORARY DIRECTORIES --------------
# This variable may be changed in local.cshrc.source,
# telling where temporary files may be written for some
# scripts which run programs that generate very large
# temporary files.
# It looks like BIRCH_TMP isn't currently used in BIRCH, but
# we'll keep it for now until we can be absolutely sure.
# It will probably reappear as a setting that can be changed
# in birchadmin.
setenv BIRCH_TMP ""


#---------------------------- OTHER SETTINGS -----------------
# noclobber must be off so that files can be overwritten
unset noclobber


# Limit core files to 0 bytes
limit coredumpsize 0M 


################################################################
#              APPLICATION-SPECIFIC SETTINGS                   #
################################################################

#-------------------------- birch, bldna, blprotein, blmarker, bltree etc.
#

if (-e $BIRCH/admin/setblenv.csh.$BIRCH_PLATFORM.source) \
    source $BIRCH/admin/setblenv.csh.$BIRCH_PLATFORM.source

#-------------------------- ACEDB
setenv ACEDB $BIRCH/acedb
# The following need to be quoted to allow for constructs such as
# open -a Textedit.app
setenv ACE_EDIT_COMMAND "$BL_TextEditor"
setenv ACE_PDF_COMMAND "$BL_PDFViewer"
setenv ACE_PS_COMMAND "$BL_PSViewer"
setenv ACE_BITMAP_VIEWER "$BL_ImageViewer"
setenv ACE_SPREADSHEET "$BL_Spreadsheet"
setenv ACE_DOCUMENT "$BL_Document"


#--------------------------- ARTEMIS
setenv ARTEMIS_HOME $BIRCH/java/artemis

#-------------------------- BOXSHADE
setenv BOXDIR $dat/boxshade

#-------------------------- CBB
setenv HISAT2_HOME $BIRCH/lib-$BIRCH_PLATFORM/hisat2

#-------------------------- FASTA
setenv FASTLIBS $DAT/fasta/fastgbs

#-------------------------- FSAP
# fsaptest will allow the user to use a test version of FSAP
#alias fsaptest $BIRCH/admin/fsaptest 



#-------------------------- GeneParser
setenv GP_HOME $dat/geneparser


#-------------------------- MAPMAKER, GENEHUNTER
setenv MAPM_LIB $DAT/mapmaker
setenv GH_DIR $DAT/genehunter
#setenv GS_LIB $MAPM_LIB/ghostscript


#-------------------------- NCBI
setenv NCBI $BIRCH/pkg/NCBI
setenv CN3D_HOME $NCBI


#--------------------------- PRIMER3
setenv PRIMER_BIN $BIRCH/$BIRCH_BIN


#--------------------------- TIGR TM4
# If your system has enough memory, set this to at least 512 or 1024
setenv TMEV_JAVA_MEMORY 256

#--------------------------- XYLEM
setenv XYLEM_PLATFORM $BIRCH_PLATFORM



################################################################
#                       SYSTEM STATISTICS                      #
#                                                              #
# Put code here for recording user traffic etc.                #
################################################################
#-------------------------- 
# BIRCH_LOGGING is not currently used in BIRCH, but is
# retained for now until we can check carefully that removing
# it won't break anything. 
setenv BIRCH_LOGGING 0


################################################################
#                     LOCAL EXTENSIONS TO BIRCH                #
################################################################

if (-e $BIRCH/local/admin/local.cshrc.source) \
      source $BIRCH/local/admin/local.cshrc.source