#!/bin/csh
#                MENUSETUP    13 December 02
# Makes link to $BIRCH/.dt/dtwmrc file
# Adds comprehensive list of X11 programs to menus. 

if !(${?BIRCH}) then
   echo '>>> Environment variable $BIRCH must be set before'
   echo '>>> running this script.'
   echo '>>> Exiting'
   exit
endif

# Make sure that psgendb doesn't run this script, which 
# would clobber the menus for everybody.
if ($HOME == $BIRCH) then
   echo This script can not be run by the BIRCH Administrator.
   echo Doing so would clobber menus for all BIRCH users.
   exit
   endif



  #---------------------------------------------------------------
  # Interactive parameter input
  set complete = 0
  while ($complete == 0)
      #Display current parameter settings
      echo '___________________________________________________________________'
      echo '                 MENUSETUP - Version 06 Dec 02                     '
      echo '                  Customize CDE menus'
      echo '-------------------------------------------------------------------'
      echo ''
      echo '1) Use customized CDE menus'
      echo '2) Revert to default CDE menus' 
      echo '   -------------------------------------------------------------'
      echo '   Type number of your choice or 0 to cancel program:'

      #Prompt for parameter to change
      set choice = $<
      switch ($choice)
        case 0:
          exit
          breaksw
        case 1:
          set complete = 1
          breaksw
        case 2:
          set complete = 1
          breaksw
        default:
          echo '>>> Invalid choice'
         breaksw
     endsw
     end # while

#-------------------------------------------------
# menu setup

switch ($choice)
  case 1:
    # Create link to $BIRCH/.dt/dtwmrc
    echo 'Replacing .dt/dtwmrc file with link to'
    echo $BIRCH/.dt/dtwmrc
    echo 'Original file is renamed with .bak extension'
    cd $home
    if (! -e .dt) mkdir .dt
    cd .dt
    if ( -e dtwmrc) mv dtwmrc dtwmrc.bak
    ln -s $BIRCH/.dt/dtwmrc dtwmrc
    
    echo Adding .bak extension to C, wsmenu and en_CA.ISO8859-1 directories
    echo to inactivate them. C and en_CA.ISO8859-1 contain dtwmrc
    echo files, while wsmenu contains a directory structure that 
    echo codes for the workspace menu. All of these directories must
    echo be renamed inorder for .dt/dtwmrc to be used for the workspace
    echo menu.
    if ((-e C) && (-d C)) mv C C.bak
    if ((-e en_CA.ISO8859-1) && (-d en_CA.ISO8859-1)) mv en_CA.ISO8859-1 en_CA.ISO8859-1.bak
    if ((-e wsmenu) && (-d wsmenu)) mv wsmenu wsmenu.bak
    
    breaksw
  case 2:
    cd $home/.dt
    if ( -e dtwmrc.bak) then
       echo Restoring .dt/dtwmrc from .dt/dtwmrc.bak
       mv dtwmrc.bak dtwmrc
    else
       echo Removing .dt/dtwmrc
       /usr/bin/rm dtwmrc 
    endif 
    
    echo Restoring C, wsmenu and en_CA.ISO8859-1 directories
    if ((-e C.bak) && (-d C.bak)) mv C.bak C
    if ((-e en_CA.ISO8859-1.bak) && (-d en_CA.ISO8859-1.bak)) mv en_CA.ISO8859-1.bak en_CA.ISO8859-1
    if ((-e wsmenu.bak) && (-d wsmenu.bak)) mv wsmenu.bak wsmenu
    breaksw
endsw

echo 'Logout and log back in for changes to take effect.'