package PGF::GapResolution::ParseSffInfo;

=head1 NAME

PGF::GapResolution::ParseSffInfo

=head1 SYNOPSIS

use PGF::GapResolution::ParseInfo;

my $obj = PGF::GapResolution::ParseInfo($sffInfoFile);
my $library = $obj->getLibrary($sffFileName);
my $sffFile = $obj->getSff($library);
my $sffType = $obj->getSffType($sffFile); # returns 'P' for paired, 'U' for unpaired.
my @sffFiles = $obj->getSffFiles();

=head1 DESCRIPTION

This module parses the sffinfo.txt file generated by parseNewblerMetrics.pl
as part of the Gap Resolution sub system and contains access methods to the
data.

The format of the $sffInfoFile mentioned above are as follows, separated by
a tab:

  1. <library>
  2. <sff file path and name>
  3. <sff type (P-paired or U-unpaired)

=head1 AUTHOR(s)

Stephan Trong

=head1 HISTORY

=over

=item *

Stephan Trong 12/11/2008 Creation

=back

=cut

#============================================================================#
use strict;
use Carp;
use Carp qw(cluck);
use FindBin qw($RealBin);
use lib "$FindBin::RealBin/../lib";

#============================================================================#
sub new {
    
    my $class = shift;
    my $sffInfoFile = shift;
    
    my $self = {};
    _parseFile($self, $sffInfoFile);
    
    bless $self, $class;
    
    
    return $self;

}

#============================================================================#
sub _parseFile {
    
    my $self = shift;
    my $file = shift;
    
    my %libraryMapping = ();
    my %sffMapping = ();
    my %sffTypeMapping = ();
    
    unless (open FH, $file ) {
        confess "ERROR: failed to open file $file: $!";
    }
    
    while ( my $entry = <FH> ) {
        chomp $entry;
        next if !length $entry;
        my @entries = split /\t/, $entry;
    
        if ( @entries < 3 ) {
            confess "ERROR: $file does not contain a vaild entry.\n";
        }
        
        my $library = $entries[0];
        my $sff = $entries[1];
        my $sffType = $entries[2];
        
        $libraryMapping{$library} = $sff;
        $sffMapping{$sff} = $library;
        $sffTypeMapping{$sff} = $sffType;
    }
        
    close FH;
    
    $self->{_libraryMapping} = \%libraryMapping;
    $self->{_sffMapping} = \%sffMapping;
    $self->{_sffTypeMapping} = \%sffTypeMapping;
    
}

#============================================================================#
sub getLibrary {
    
    my $self = shift;
    my $sffFile = shift;
    
    my $library = exists $self->{_sffMapping}{$sffFile} ?
        $self->{_sffMapping}{$sffFile} : '';
    
    return $library;
}

#============================================================================#
sub getSff {
    
    my $self = shift;
    my $library = shift;
    
    my $sff = exists $self->{_libraryMapping}{$library} ?
        $self->{_libraryMapping}{$library} : '';
    
    return $sff;
}

#============================================================================#
sub getSffType {
    
    my $self = shift;
    my $sff = shift;
    
    my $sffType = exists $self->{_sffTypeMapping}{$sff} ?
        $self->{_sffTypeMapping}{$sff} : '';
        
    return $sffType;
}

#============================================================================#
sub getSffFiles {
    
    my $self = shift;
    
    return keys %{$self->{_sffMapping}};
    
}
    
#============================================================================#
1;